Saberexcel - site das macros

Essa macro do aplicativo Microsoft Excel VBA, inserindo uma foto, um gráfico, no comentário através de vba(Visual Basic Application) selecione a imagem e logo em seguida acione a macro que através de um input box pedira a extensão do
arquivo (normalmente eu insiro arquivos com extensão (*.Gif)

Sub Imagem_no_comentario()
Dim ch As ChartObject
Dim dWidth As Double
Dim dHeight As Double
Dim ws As Worksheet
Dim sName As String
Dim cmt As Comment
Dim sPath As String
Dim sFile As String
Dim rng As Range

Set ws = ActiveSheet
Set rng = ActiveCell

sPath = ThisWorkbook.Path & "\"
sName = InputBox("Nome da imagem(nao extensão)", "Nome do Arquivo")

If sName = "" Then sName = "Picture_" & Format(Date, "dd-mm-yyyy")
sFile = sPath & sName & ".gif"

dWidth = Selection.Width
dHeight = Selection.Height

Selection.Cut
Set ch = ws.ChartObjects.Add(Left:=rng.Left, Top:=rng.Top, _
Width:=dWidth, Height:=dHeight)
ch.Chart.Paste
rng.Activate
ch.Chart.Export sFile
ch.Delete

Set cmt = rng.AddComment
cmt.Text Text:=""
With cmt.Shape

.Fill.UserPicture sFile
.Width = dWidth
.Height = dHeight
End With

End Sub

 
Aprenda tudo sobre o Aplicativo Microsoft Excel VBA(Visual Basic Application), sozinho, com baixo custo, praticando com os produtos didáticos Saberexcel