Usando critérios multiplos para busca de determinados números
Saberexcel - Dicas de Fórmulas e Funções

Essas fórmulas do Aplicativo Microsoft Excel, retornam determinado dado, baseado em uma busca em critérios múltiplos,


Quando você digitar os critérios "Nome" na Célula(D1) e SobreNome na Célula(E1)
Vai retornar a idade:

Primeiro nome na...........: Coluna(A)
Sobrenome na..............: Coluna(B)
Idade na coluna.............: Coluna(C)

Critérios
Primeiro Nome na...........: Célula(D1)
Ultimo nome na .............: Célula(E1)


Fórmula usada....: {=SOMARPRODUTO((A1:A1001=D1)*(B1:B1001=E1)*(C1:C1001))}
Retorna .........: "Idade que esta na célula(C1) baseados nos nomes e sobrenomes que estão células($D$1)e ($C$1 )

Concatenando dados para uma mensagem..:
Mensagem correta....: Lucia [ Ferrarini ] sobrenome correto, tem [ 35 ] Anos de idade
Mensagem #Erro#....: Sobrenome de: [ Lucia ] não é : [ Menezes ] esta errado!

Formula usada....:
=SE(I16=0;"Sobrenome de: [ "&D1&" ] não é : [ "&E1&" ] esta errado!";D1&" [ "&E1&" ] sobrenome correto, tem [ "&I16&" ] Anos de idade"

ou

Formula usada....: {=SOMA((A1:A1002=D1)*(B1:B1002=E1)*C1:C1002)}
Retorna............: idade (35)

ou poderá também usar essa fórmula

Formula usada....: {=SOMA(SE(A1:A1002=D1;SE(B1:B1002=E1;C1:C1002)))}

usando a função ìndice e corresp

Formula usada....: {=ÍNDICE(C1:C1002;CORRESP(1;(A1:A1002=D1)*(B1:B1002=E1);0))}

Fórmula retorna um endereço baseado em numero menor coluna(A)
Saberexcel - dicas de fórmulas e funções

Essa fórmula retorna o endereço com numero da coluna(A) do menor
número digitado na coluna(B)

Exemplo................: se o menor número na Coluna(B)for 450, então retornará
Fórmula usada.........: =ENDEREÇO(MÍNIMO(B:B);COL(A:A))
Retorno.................: $A$450

Exemplo................: se o menor número na Coluna(B) for 450, então retornará
Fórmula usada.........: =ENDEREÇO(MÍNIMO(B:B);1)
Retorno.................: $A$450



Aprenda tudo sobre o Aplicativo Microsoft Excel VBA com SaberExcel

Fórmula matricial retorna o endereço dos três maiores números na coluna(A)
Saberexcel - dicas de fórmulas e funções


Para que a fórmula maticial retorne os endereços dos tres maiores números existentes na
Coluna(A) e números correspondentes na Coluna(B), selecione a célula que contém a fórmula
e selecione mais (tres) células abaixo, em seguida tecle (Ctrl + Shift + Enter)


Fórmula usada......: {=CÉL("address";ÍNDICE(A1:A10;CORRESP(MAIOR(A1:A10;{1;2;3});A1:A10;0)))}
Fórmula usada......: {=CÉL("address";ÍNDICE(A1:A10;CORRESP(MAIOR(A1:A10;{1;2;3});A1:A10;0)))}
Fórmula usada......: {=CÉL("address";ÍNDICE(A1:A10;CORRESP(MAIOR(A1:A10;{1;2;3});A1:A10;0)))}
Retorno (exemplo): $A$10
ou

Fórmula usada......: {=CÉL("address";ÍNDICE(A1:A10;CORRESP(MAIOR(A1:A10;LIN(INDIRETO("1:3")));A1:A10;0)))}
Fórmula usada......: {=CÉL("address";ÍNDICE(A1:A10;CORRESP(MAIOR(A1:A10;LIN(INDIRETO("1:3")));A1:A10;0)))}
Fórmula usada......: {=CÉL("address";ÍNDICE(A1:A10;CORRESP(MAIOR(A1:A10;LIN(INDIRETO("1:3")));A1:A10;0)))}

Retorna o endereço da célula onde localiza o número da célula(A1)

Fórmula usada......: {=CÉL("endereço";ÍNDICE(B1:B10;CORRESP(MAIOR(SE(A1:A10=A1;B1:B10;"");{1;2;3});B1:B10;0)))}


Fórmula usada com concatenação obtendo a mensagem:
Valor correspondente [ 125 ] é : [ 154 ] esta localizado na célula : [ $B$5 ]
Fórmula usada:
{="Valor de: [ "&INDIRETO(CÉL("endereço";ÍNDICE(B1:B10;CORRESP(MAIOR(SE(A1:A10=A1;B1:B10;"");{1;2;3});B1:B10;0))))& " ] esta localizado na célula : [ " &CÉL("endereço";ÍNDICE(B1:B10;CORRESP(MAIOR(SE(A1:A10=A1;B1:B10;"");{1;2;3});B1:B10;0)))&" ]"}

ou

Fórmula usada......: {=CÉL("endereço";ÍNDICE(B1:B10;CORRESP(MAIOR(SE(A1:A10=A1;B1:B10;"");LIN(INDIRETO("1:3")));B1:B10;0)))}
Fórmula usada......: {=CÉL("endereço";ÍNDICE(B1:B10;CORRESP(MAIOR(SE(A1:A10=A1;B1:B10;"");LIN(INDIRETO("1:3")));B1:B10;0)))}



Produtos didáticos Saberexcel - Aprenda MS Excel VBA com qualidade:



Aprenda tudo sobre o Aplicativo Microsoft Excel VBA com Saberexcel

Formula do Aplicativo Microsoft Excel retorna o número baseado no indice criterio da coluna(B)

Suponhamos que voce tenha uma lista de números na coluna(A) de celulas(A11 a A10), e que o sétimo número é 2475,
então na coluna(B) se voce inserir o número 7, retornará o sétimo número.

Fórmula usada.......: =ÍNDICE(A:A;MÍNIMO((B:B)))
Celula(B1).............: 7


Concatenar dados para emiitir uma mensagem
Mensagem concatenada:...: "O 7 º.) ítem na coluna(A) é: 2.475 "
Fórmula usada..................: ="O "&B1&" º.) ítem "&" na coluna(A) é: "&TEXTO(E9;"#.##0")
Observe que fiz uma formatação no numero de resposta, separaçao de milhar (Texto(E9; "#.##0")

Aprenda tudo sobre o Aplicativo Microsoft Excel VBA com Saberexcel

Formula retorna a soma de valores que vencem na data de hoje


Essa fórmula do Aplicativo Microsoft Excel, soma valores equivalentes a data de hoje() na coluna(B)
Fórmula usada.....: =SOMARPRODUTO((MÊS(A1:A366)=MÊS(HOJE()))*(DIA(A1:A366)=DIA(HOJE()))*B1:B366)
Retorno.............: (a soma dos valores equivalentes a data de hoje na coluna(B)

Concatenando dados com resultado da fórmula acima:
Mensagem ........: Hoje dia: [sáb-07-ago-2010 ] temos 3.376,87 para receber
Fórmula usada....: ="Hoje dia: ["& TEXTO( HOJE();"ddd-dd-mmm-aaa") &" ]" &" temos "&TEXTO(G6;"#.##0,00")&" para receber"

Localiza a primeira data do dia de hoje e retorna o valor contido na colun(B)
Fórmula usada....: =ÍNDICE(B1:B366;CORRESP(1;(MÊS(A1:A366)=MÊS(HOJE()))*(DIA(A1:A366)=DIA(HOJE()));0))
Retorno............: "o primeiro valor correspondente à data de hoje()"

Concatenando dados com resultado da fórmula acima
Mensagem ........: Hoje é [ 07-ago-2010 ] e o primeiro valor é [ 145,87 ]
Fórmula usada....: ="Hoje é [ "&TEXTO(HOJE();"dd-mmm-aaaa")& " ] e o primeiro valor é [ "&G24&" ]"



Aprenda Microsoft Excel VBA com qualidade - Saberexcel